;1、正方形 (:B表示边长)
   TO ZFX :B
     REPEAT 4[FD :B RT 90]
   END

;2、长方形 (:B表示宽, :A表示长)
   TO CFX :A :B
     REPEAT 2[FD :A RT 90 FD :B RT 90]
   END

;3、三角形 (:B表示边长)
   TO SJX :B
     REPEAT 3[FD :B RT 120]
   END

;4、正多边形 (:N表示边数, :B表示边长)
   TO DBX :N :B
     REPEAT :N[FD :B RT 360/:N]
   END

;5、圆(:R表示半径,在LOGO语言中可以直接用PI来代替π的值)
   TO YUAN :R
     REPEAT 360[RT 0.5 FD :R*PI/180 RT 0.5]
   END            

;6、左弧 (:N表示弧度, :R表示半径)
   TO LHU :N :R
     REPEAT :N[FD :R*PI/180 LT 1]
   END

;7、右弧 (:N表示弧度, :R表示半径)
   TO RHU :N :R
     REPEAT :N[FD :R*PI/180 RT 1]
   END

;8、左叶 (:N表示弧度, :R表示半径)
   TO LY :N :R
     REPEAT 2[LHU :N :R LT 180-:N]
   END

;9、右叶 (:N表示弧度, :R表示半径)
   TO RY :N :R
     REPEAT 2[RHU :N :R RT 180-:N]
   END

;10、平行四边形
   TO PXSBX :B1 :B2 :J
     REPEAT 2[FD :B1 RT :J FD :B2 RT 180-:J]
   END

;11、空心矩形 (:A表示长, :B表示宽)
   TO KXJX :A :B
     STAMPRECT :A :B
   END

;12、实心矩形 (:A表示长, :B表示宽)
   TO SXJX :A :B
     (STAMPRECT :A :B ”TRUE)
   END

;13、空心椭圆 (:X表示长半轴, ;Y表示短半轴)
   TO KXTY :X :Y
     STAMPOVAL :X :Y
   END

;14、实心椭圆 (:X表示长半轴, ;Y表示短半轴)
   TO SXTY :X :Y
     (STAMPOVAL :X :Y ”TRUE)
   END

;15、空心正多角形 (:N表示边数, :B表示边长)
   TO KXJ :N :B
     REPEAT :N[FD :B RT 720/:N FD :B LT 360/:N]
   END

;16、一般正多角星 (一般正多角星的内角角度为NJ=（N-2K）*180/N，其中K为整数，K的范围在1＜K＜N/2，且K与N没有公因数。)
  TO YBJ :N :B :K
     REPEAT :N[FD :B RT :K*360/:N]
  END
